File:Airy Formula.svg
Page contents not supported in other languages.
Appearance
Size of this PNG preview of this SVG file: 800 × 400 pixels. Other resolutions: 320 × 160 pixels | 640 × 320 pixels | 1,024 × 512 pixels | 1,280 × 640 pixels | 2,560 × 1,280 pixels.
Original file (SVG file, nominally 800 × 400 pixels, file size: 54 KB)
This is a file from the Wikimedia Commons. Information from its description page there is shown below. Commons is a freely licensed media file repository. You can help. |
Summary
DescriptionAiry Formula.svg |
Deutsch: Die hier geplottete Airy-Formel gibt die Transmission eines Fabry-Pérot Interferometers (FPI) an. Für höhere Finessen ℱ wird nicht-resonantes Licht besser unterdrückt. Die Linienbreite δ ist für große Finessen näherungsweise ∆ν/ℱ mit dem Freien Spektral Bereich (FSR) ∆ν.
English: The Airy formula (not to be confused with the Airy function) gives the transmitted intensity of a Fabry-Pérot Interefometer (FPI).
|
Date | |
Source | Own work |
Author | Kondephy |
Licensing
I, the copyright holder of this work, hereby publish it under the following license:
This file is licensed under the Creative Commons Attribution-Share Alike 4.0 International license.
- You are free:
- to share – to copy, distribute and transmit the work
- to remix – to adapt the work
- Under the following conditions:
- attribution – You must give appropriate credit, provide a link to the license, and indicate if changes were made. You may do so in any reasonable manner, but not in any way that suggests the licensor endorses you or your use.
- share alike – If you remix, transform, or build upon the material, you must distribute your contributions under the same or compatible license as the original.
Gnuplot source
reset # clear all styles, variables ...
# SVG output
set terminal svg size 800,400 fname 'Verdana, Helvetica, Arial, sans-serif
set output 'airyformel.svg'
set samples 1001 # enough points to make it look nice
# set font sizes for labels, legend and title
set xtics font ",16"
set xlabel font ",16"
set ytics font ",16"
set ylabel font ",16"
set key font ",20"
set title font ",20"
set label font ",20"
set grid # activate grid to indicate position of dips and peaks
set xrange[0:2*pi] # function is pi-periodic
set yrange[0:1] # it's normalized
# set labels with unicode greek letters
set xlabel 'φ=2π ν/(∆ν)'
set ylabel 'I/I_{max}'
# set grid lines where it's important for the understanding
set xtics ('0' 0,\
'π/2' pi/2,\
'π' pi,\
'3π/2' 3*pi/2,\
'2π' 2*pi)
set ytics('0' 0,\
'0.5' 0.5,\
'1' 1)
# line colors copied from viridis colormap by Eric Firing
# licensed under CC0 https://creativecommons.org/publicdomain/zero/1.0/
# https://github.com/Gnuplotting/gnuplot-palettes/blob/master/viridis.pal
set style line 1 lw 2 lt 1 lc rgb '#440154' # dark purple
set style line 2 lw 3 lt 1 lc rgb '#2c718e' # blue
set style line 3 lw 3 lt 1 lc rgb '#aadc32' # lime green
# modified the formula, so you just have to insert another value for Finesse ℱ
I500(x) =1/(1+(2*500/pi)**2*(sin(x))**2)
I50(x) =1/(1+(2* 50/pi)**2*(sin(x))**2)
I5(x) =1/(1+(2* 5/pi)**2*(sin(x))**2)
set key top right # legend in the upper right
# set arrows to indicate the linewidth
set style arrow 1 head filled size screen 0.03,15 ls 2 front
set arrow from pi*4/5, 0.5 to pi*49/50,0.5 as 1
set arrow from pi*6/5, 0.5 to pi*51/50,0.5 as 1
set label 'δ∝∆ν/ℱ' at first pi*6/5, 0.502 font ",20" # label next to arrow
plot I500(x) ls 1 title 'ℱ=500',\
I50(x) ls 2 title 'ℱ= 50',\
I5(x) ls 3 title 'ℱ= 5'
unset output # close file
Items portrayed in this file
depicts
4 November 2016
image/svg+xml
a0a12e89efc97ec7a6d2a0e54f161f3a40cdf9ee
55,792 byte
400 pixel
800 pixel
File history
Click on a date/time to view the file as it appeared at that time.
Date/Time | Thumbnail | Dimensions | User | Comment | |
---|---|---|---|---|---|
current | 15:02, 4 November 2016 | 800 × 400 (54 KB) | Kondephy | User created page with UploadWizard |
File usage
No pages on the English Wikipedia use this file (pages on other projects are not listed).
Global file usage
The following other wikis use this file:
- Usage on de.wikipedia.org
Metadata
This file contains additional information, probably added from the digital camera or scanner used to create or digitize it.
If the file has been modified from its original state, some details may not fully reflect the modified file.
Short title | Fabry–Pérot Interferometer: Transmission |
---|---|
Width | 800 |
Height | 400 |
Retrieved from "https://en.wikipedia.org/wiki/File:Airy_Formula.svg"