File:BlackbodySpectrum loglog en.svg
Page contents not supported in other languages.
Appearance
![File:BlackbodySpectrum loglog en.svg](http://upload.wikimedia.org/wikipedia/commons/thumb/8/84/BlackbodySpectrum_loglog_en.svg/800px-BlackbodySpectrum_loglog_en.svg.png)
Size of this PNG preview of this SVG file: 800 × 580 pixels. Other resolutions: 320 × 232 pixels | 640 × 464 pixels | 1,024 × 742 pixels | 1,280 × 928 pixels | 2,560 × 1,856 pixels | 1,600 × 1,160 pixels.
Original file (SVG file, nominally 1,600 × 1,160 pixels, file size: 75 KB)
![]() | This is a file from the Wikimedia Commons. Information from its description page there is shown below. Commons is a freely licensed media file repository. You can help. |
Summary
DescriptionBlackbodySpectrum loglog en.svg |
Deutsch: Plancksches Strahlungsspektrum für Temperaturen von 100 K bis 10000 K in einem doppeltlogarithmischen Koordinatensystem. Deutsche Version
English: Black body spectrum for temperatures between 100 K and 10000 K in a log-log diagram.
Türkçe: 100K ve 1000K sıcaklık aralığında kara cisim spektrumu |
Date | |
Source | Own work |
Author | Prog |
gnuplot source code
set terminal svg size 1600,1160 fname 'Verdana' fsize 34 lw 3
set output 'BlackbodySpectrum loglog.svg'
set multiplot
# the visible light plot
set pm3d map
set palette color
set xrange [0.380:0.780]
set yrange [*:*]
set noxtics
set noborder
unset ztics
unset ytics
set samples 50
set noborder
unset colorbox
set nokey
set logscale x
# # full saturation
# set palette defined ( \
# 0.00 0.000 0.000 0.000, \
# 0.08 0.285 0.000 0.547, \
# 0.20 0.148 0.016 0.918, \
# 0.30 0.004 0.578 0.887, \
# 0.36 0.000 0.844 0.531, \
# 0.50 0.004 0.715 0.000, \
# 0.68 0.863 0.797 0.000, \
# 0.77 0.996 0.371 0.000, \
# 0.84 0.918 0.148 0.000, \
# 0.90 0.781 0.047 0.000, \
# 1.00 0.000 0.000 0.000 )
set palette defined ( \
0.00 0.8000 0.8000 0.8000, \
0.08 0.8570 0.8000 0.9094, \
0.20 0.8296 0.8032 0.9836, \
0.30 0.8008 0.9156 0.9774, \
0.36 0.8000 0.9688 0.9062, \
0.50 0.8008 0.9430 0.8000, \
0.68 0.9726 0.9594 0.8000, \
0.77 0.9992 0.8742 0.8000, \
0.84 0.9836 0.8296 0.8000, \
0.90 0.9562 0.8094 0.8000, \
1.00 0.8000 0.8000 0.8000 )
# l/r-margin = 0.107+(1+log(lambda))/3 * (0.858 - 0.107)
set lmargin at screen 0.252
set rmargin at screen 0.330
set bmargin at screen 0.132
set tmargin at screen 0.876
splot x
reset
# the diagrams
set lmargin at screen 0.107
set rmargin at screen 0.858
set bmargin at screen 0.132
set tmargin at screen 0.876
//# # English
//set title "Black body spectrum" font ",44"
//set xlabel "Wavelength [µm]"
//set ylabel "Spectral radiant emittance [W/(m² µm)]"
//set y2label "Spectral radiance [W/(m² µm sr)]"
# Turkish
set title "Kara Cisim Spektrumu" font ",44"
set xlabel "Dalga Boyu [µm]"
set ylabel "Spektral Işınım Emisyonu [W/(m² µm)]"
set y2label "Spektral Işınım [W/(m² µm sr)]"
# # German
# set title "Plancksches Strahlungsspektrum" font ",44"
# set xlabel "Wellenlänge [µm]"
# set ylabel "Spektrale spezifische Ausstrahlung [W/(m² µm)]"
# set y2label "Spektrale Strahldichte [W/(m² µm sr)]"
set xrange [0.1:100]
set yrange [0.01:10**10]
set y2range [0.01 / pi:10**10 / pi]
set format y "10^{%L}"
set format y2 "10^{%L}"
set logscale x
set logscale y
set logscale y2
set ytics nomirror
set grid
set nokey
k = 1.38064852 * 10**-23
h = 6.62607004 * 10**-34
c = 299792458
raw_f(lambda, T) = (2 * pi * h * c**2) / (lambda**5 * (exp((h * c) / (lambda * k * T)) - 1))
use_f(lambda, T) = raw_f(lambda / 10**6, T) / 10**6
set y2tics
set label 1 at 25, 0.04 '200K' center rotate by 0 front
set label 2 at 6.4, 4 '400K' center rotate by 0 front textcolor rgb '#FF0000'
set label 3 at 3.8, 50 '600K' center rotate by 0 front
set label 4 at 1.95, 1500 '3000K' center rotate by 0 front
set label 5 at 0.68, 400000 '6000K' center rotate by 0 front
set label 6 at 0.36, 10000000 '8000K' center rotate by 0 front textcolor rgb '#FFBB05'
set label 7 at 0.22, 180000000 '10000K' center rotate by 0 front
plot \
use_f(x, 200) lc black lw 1, \
use_f(x, 400) lc rgb '#FF0000' lw 2, \
use_f(x, 600) lc black lw 1, \
use_f(x, 3000) lc black lw 1, \
use_f(x, 8000) lc black lw 1, \
use_f(x, 5777) lc rgb '#FFBB05' lw 2, \
use_f(x, 10000) lc black lw 1
Licensing
I, the copyright holder of this work, hereby publish it under the following license:
![w:en:Creative Commons](https://upload.wikimedia.org/wikipedia/commons/thumb/7/79/CC_some_rights_reserved.svg/90px-CC_some_rights_reserved.svg.png)
![attribution](https://upload.wikimedia.org/wikipedia/commons/thumb/1/11/Cc-by_new_white.svg/24px-Cc-by_new_white.svg.png)
![share alike](https://upload.wikimedia.org/wikipedia/commons/thumb/d/df/Cc-sa_white.svg/24px-Cc-sa_white.svg.png)
This file is licensed under the Creative Commons Attribution-Share Alike 4.0 International license.
- You are free:
- to share – to copy, distribute and transmit the work
- to remix – to adapt the work
- Under the following conditions:
- attribution – You must give appropriate credit, provide a link to the license, and indicate if changes were made. You may do so in any reasonable manner, but not in any way that suggests the licensor endorses you or your use.
- share alike – If you remix, transform, or build upon the material, you must distribute your contributions under the same or compatible license as the original.
Captions
Add a one-line explanation of what this file represents
Kara cisim ışınım spektrumu
Items portrayed in this file
depicts
10 July 2017
image/svg+xml
bef124bb45a6a3c4727443d44b345d270b89e826
76,711 byte
1,160 pixel
1,600 pixel
File history
Click on a date/time to view the file as it appeared at that time.
Date/Time | Thumbnail | Dimensions | User | Comment | |
---|---|---|---|---|---|
current | 15:27, 10 July 2017 | ![]() | 1,600 × 1,160 (75 KB) | Prog | User created page with UploadWizard |
File usage
No pages on the English Wikipedia use this file (pages on other projects are not listed).
Global file usage
The following other wikis use this file:
- Usage on ru.wikipedia.org
Metadata
This file contains additional information, probably added from the digital camera or scanner used to create or digitize it.
If the file has been modified from its original state, some details may not fully reflect the modified file.
Short title | Gnuplot |
---|---|
Image title | Produced by GNUPLOT 5.0 patchlevel 3 |
Width | 1600 |
Height | 1160 |
Retrieved from "https://en.wikipedia.org/wiki/File:BlackbodySpectrum_loglog_en.svg"