to share – to copy, distribute and transmit the work
to remix – to adapt the work
Under the following conditions:
attribution – You must give appropriate credit, provide a link to the license, and indicate if changes were made. You may do so in any reasonable manner, but not in any way that suggests the licensor endorses you or your use.
share alike – If you remix, transform, or build upon the material, you must distribute your contributions under the same or compatible license as the original.
set term svg size 800,600 enhanced font 'Times,12'
set output 'Natural_Logarithm_All.svg'
set multiplot
set xlabel "x"
set ylabel "y"
set zlabel "z"
set xrange [-2.5:2.5]
set yrange [-2.0:2.0]
set zrange [-3:4]
set box
unset colorbox
#set view 65,45
set cntrparam levels auto 20
set contour base
set isosamples 60,60
set samples 60,60
set pm3d
set hidd
unset key
set ticslevel 0
i = {0.0,1.0}
# Draw the surface of Re(ln(x+i*y))
set palette defined (-1 "blue", 1 "pink")
splot real(log(x+i*y))
# Draw the surface of |Im(ln(x+i*y))|
set palette defined (-1 "yellow", 1 "orange")
splot abs(imag(log(x+i*y)))
# Draw the surface of |ln(x+i*y)|
set palette defined (-1 "red", 1 "orange")
splot abs(log(x+i*y))
# Draw the lines
unset cntrparam
unset contour
set isosamples 20,20
set samples 20,20
unset pm3d
unset hidd
# Draw the lines of Re(ln(x+i*y))
splot real(log(x+i*y)) lt 2 lc rgb "black" lw 0.1
# Draw the lines of |Im(ln(x+i*y))|
splot abs(imag(log(x+i*y))) lt 2 lc rgb "black" lw 0.1
# Draw the lines of |ln(x+i*y)|
splot abs(log(x+i*y)) lt 2 lc rgb "black" lw 0.1
unset multiplot
set term x11
set output
Captions
Add a one-line explanation of what this file represents